
; LOGICAL EXCLUSIVE OR
; ********************
; DIGITAL COMPUTER CONTROLS,INC.
; 116-0028A
;
; COMPUTES THE EXCLUSIVE OR OF TWO UNSIGNED NUMBERS
; INPUT:        A IN AC0, B IN AC1
; OUTPUT:       A .XOR. B IN AC0
; CALLING SEQUENCE:
;       JSR     .XOR
;       RETURN
; DESTROYED:    AC0, AC3, CARRY
; UNCHANGED:    AC1, AC2
; METHOD:       A .XOR. B = A + B -2(A .AND. B)
	.REL	0
	.TITL	.XOR
.XOR:   STA 3,.CD03     ; SAVE RETURN
        MOV 1,3         ; B TO AC2
        ANDZL 0,3       ; 2(A .AND. B)
        ADD 1,0         ; A + B
        SUB 3,0         ; A + B -2(A .AND. B)
        JMP @.CD03      ; RETURN

.CD03:  0               ; SAVE RETURN
	.END		;LOGICAL EXCLUSIVE OR
